第３章 プログラミング
■ プログラミング概要
エントリー１は、ＰＣ本体のキーボードラインから簡単なコマンドを送ることにより、より高度な活用が可能です。
ＰＣ本体のキーボードラインからエントリー１にデータを送るための手順を、ＢＡＳＩＣサブルーチンとして次に示します。
ユーザー自身で本サブルーチンを参考に、エントリー１コントロールプログラムを自由に作成してください。
■ サブルーチン
ＢＡＳＩＣ言語で記述した、標準的なサブルーチンを示します。
また他言語へ移植を検討される場合は、事項のサブルーチン解説をご覧ください。
サブルーチン名は"＊ＳＥＮＤ．ＤＡＴ"です。
コマンドナンバー、パラメーターを、変数名"ＳＥＮＤ＄"の中に代入し、サブ
ルーチン（＊ＳＥＮＤ．ＤＡＴＡ）をコールします。
ここではサブルーチンの実際使用例として、ＬＣＤ表示をクリアして、
”ＨＥＬＬＯ！”と表示させてみます。
＜参 照＞
コマンドの詳細については、第４章のコマンドリファレンスを
参照してください。
ＬＣＤ表示クリア
メッセージ表示
100 '
110 ' LCD ヒョウジヲ クリアシ HELLO! ト ヒョウジスル
120 '
130 SEND$=CHR$(&H1B)+CHR$(&H12)+CHR$(&H0) '１２ｈ ＬＣＤ表示クリア
140 GOSUB *SEND.DATA
150 SEND$=CHR$(&H1B)+CHR$(&H1C)+CHR$(&H6)+"HELLO!" '１ｃｈ メッセージ表示
160 GOSUB *SEND.DATA
170 '
180 END
190 '
200 '--------------------------------------------------
210 ' サフ゛ル−チン
220 '--------------------------------------------------
230 *SEND.DATA
240 OUT &H2,(&H2 OR INP(&H2)) : DEF SEG=0
250 SP.TABLE.1 =PEEK(&H538) : SP.TABLE.2 =PEEK(&H53A)
260 TB.OFFSET.1=PEEK(&H522) : TB.OFFSET.2=PEEK(&H523)
270 FOR I.SEND=1 TO LEN(SEND$)
280 OUT &H43,&H17:OUT &H41,ASC(MID$(SEND$,I.SEND,1)): A%=INP(&H41)
290 FOR J.SEND=1 TO 36: NEXT J.SEND
300 NEXT I.SEND
310 OUT &H43,&H17
320 POKE &H538,SP.TABLE.1 : POKE &H53A,SP.TABLE.2
330 POKE &H522,TB.OFFSET.1 : POKE &H523,TB.OFFSET.2
340 A%=INP(&H41): A%=INP(&H41)
350 OUT &H2,(&HFD AND INP(&H2))
360 WHILE INKEY$<>"" : WEND
370 RETURN
380 '--------------------------------------------------
■ サブルーチン解説
- １．ＯＵＴ ＆Ｈ２，（＆Ｈ２ ＯＲ ＩＮＰ（＆Ｈ２））
- 以後の処理中はキーボードからの割込みを禁止します。
Ｉ／Ｏポートアドレス＆Ｈ２はＩＭＲ（割込みマスクレジスタ）となっていて、マスクすべき割込みラインのビットを格納しています。
ＩＭＲのセットされているビットに対応したＩＲ入力の割り込み要求は保留されます。
- ２．ＤＥＦ ＳＥＧ＝０
- セグメントのベースアドレスをシステム共通域に設定します。
- ３．ＳＰ．ＴＡＢＬＥ．１ ＝ＰＥＥＫ（＆Ｈ５３８）
ＳＰ．ＴＡＢＬＥ．２ ＝ＰＥＥＫ（＆Ｈ５３Ａ）
ＴＢ．ＯＦＦＳＥＴ．１ ＝ＰＥＥＫ（＆Ｈ５２２）
ＴＢ．ＯＦＦＳＥＴ．２ ＝ＰＥＥＫ（＆Ｈ５２３）
- ワークエリアの一部を保護します。
- ４．ＯＵＴ ＆Ｈ４３，＆Ｈ１７
- ＰＣ本体側のＵＳＡＲＴ（８２５１Ａ シリアルデータ送受信用ＩＣ）を、送信可の状態にします。
＜参 照＞ Ｉ／Ｏポート表
- ５．ＯＵＴ ＆Ｈ４１，ＡＳＣ （ＭＩＤ＄（ＳＥＮＤ＄，Ｉ．ＳＥＮＤ，１））
- エントリー１へデータを送信します。
実際使用例では、コマンドやメッセージ表示データを、文字列にして、サブルーチンを呼んでいます。
そしてサブルーチン内では、その文字列を１文字づつ出力しています。
- ６．Ａ％＝ＩＮＰ（＆Ｈ４１）
- １文字出力した後に、ダミーデータを取込みます。
＜参 照＞ Ｉ／Ｏポート表
- ７．ＦＯＲ Ｊ．ＳＥＮＤ＝１ ＴＯ ３６：ＮＥＸＴ Ｊ．ＳＥＮＤ
- ＰＣ本体からコマンドや、表示データ列をエントリー１に送出するにあたりデータの送出タイミングをとります。
＜ご注意＞
エントリー１の、ＬＣＤ表示やコマンドが正常に動作することが確認できればループの回数をユーザー自身で増減してください。
（プログラム内では３６回）また、ＰＣの機種により適切な値（ループ回数値）を使用してください。
- ８．ＰＯＫＥ ＆Ｈ５３８，ＳＰ．ＴＡＢＬＥ．１
ＰＯＫＥ ＆Ｈ５３Ａ，ＳＰ．ＴＡＢＬＥ．２
ＰＯＫＥ ＆Ｈ５２２，ＴＢ．ＯＦＦＳＥＴ．１
ＰＯＫＥ ＆Ｈ５２３，ＴＢ．ＯＦＦＳＥＴ．２
- ワークエリアの一部保護した所を書き戻します。
- ９．ＯＵＴ ＆Ｈ２，（＆ＨＦＤ ＡＮＤ ＩＮＰ（＆Ｈ２））
- キーボードからの割込み禁止を解除します。
- 10．ＷＨＩＬＥ ＩＮＫＥＹ＄＜＞””：ＷＥＮＤ
- ＢＡＳＩＣのキーバッファをクリアーします。
■ ＢＡＳＩＣサンプルプログラム
ＢＡＳＩＣ言語で記述されている本サンプルプログラムは、エントリー１のコマンドをメニューの中から選ぶことにより、全てのコマンドを試せます。
コマンドの詳細については、第４章のコマンドリファレンスを参照してください。
サンプルプログラムはこちら
目次へ戻る